Pull request

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
use "json"
use "promises"
use req = "request"
use ut = "uri/template"

type PullRequestOrError is (PullRequest | req.RequestError)

class val PullRequest
  """
  A GitHub pull request. Provides a convenience method to fetch the files
  changed in this pull request.
  """
  let _creds: req.Credentials
  let number: I64
  let title: String
  let body: (String | None)
  let state: String
  let labels: Array[Label] val
  let base: PullRequestBase
  let url: String
  let html_url: String
  let files_url: String
  let comments_url: String

  new val create(
    creds: req.Credentials,
    number': I64,
    title': String,
    body': (String | None),
    state': String,
    labels': Array[Label] val,
    base': PullRequestBase,
    url': String,
    html_url': String,
    comments_url': String)
  =>
    _creds = creds
    number = number'
    title = title'
    body = body'
    state = state'
    labels = labels'
    base = base'
    url = url'
    html_url = html_url'
    comments_url = comments_url'
    files_url = url + "/files"

  fun get_files(): Promise[PullRequestFilesOrError] =>
    """
    Fetches the files changed in this pull request.
    """
    GetPullRequestFiles.by_url(files_url, _creds)

primitive GetPullRequest
  """
  Fetches a single pull request by owner, repo, and number.
  """
  fun apply(
    owner: String,
    repo: String,
    number: I64,
    creds: req.Credentials): Promise[PullRequestOrError]
  =>
    match \exhaustive\ ut.URITemplateParse(
      "https://api.github.com/repos" +
      "{/owner}{/repo}/pulls{/number}")
    | let tpl: ut.URITemplate =>
      let vars = ut.URITemplateVariables
        .> set("owner", owner)
        .> set("repo", repo)
        .> set("number", number.string())
      let u: String val = tpl.expand(vars)
      by_url(u, creds)
    | let e: ut.URITemplateParseError =>
      Promise[PullRequestOrError] .> apply(
        req.RequestError(
          where message' = e.message))
    end

  fun by_url(
    url: String,
    creds: req.Credentials
  ): Promise[PullRequestOrError]
  =>
    """
    Fetches a pull request from a URL.
    """
    let p = Promise[PullRequestOrError]
    let r =
      req.ResultReceiver[PullRequest](
        creds,
        p,
        PullRequestJSONConverter)

    req.JSONRequester.get(creds, url, r)
    p

primitive PullRequestJSONConverter is
  req.JSONConverter[PullRequest]
  """
  Converts a JSON object from the pulls API into a PullRequest.
  """
  fun apply(
    json: JSONNav,
    creds: req.Credentials): PullRequest ?
  =>
    """
    Builds a PullRequest from its JSON representation.
    """
    let number = json("number").as_i64()?
    let title = json("title").as_string()?
    let body =
      JSONNavUtil.string_or_none(json("body"))?
    let state = json("state").as_string()?

    let labels = recover trn Array[Label] end
    for i in json("labels").as_array()?.values() do
      let l =
        LabelJSONConverter(JSONNav(i), creds)?
      labels.push(l)
    end

    let base =
      PullRequestBaseJSONConverter(
        json("base"), creds)?

    let url = json("url").as_string()?
    let html_url = json("html_url").as_string()?
    let comments_url =
      json("comments_url").as_string()?

    PullRequest(
      creds,
      number,
      title,
      body,
      state,
      consume labels,
      base,
      url,
      html_url,
      comments_url)