Diagnostics

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
use "immutable-json"
use "ast"

class ref Diagnostic
    """
    See: https://microsoft.github.io/language-server-protocol/specifications/lsp/3.17/specification/#diagnostic
    """
    let range: LspPositionRange
    let severity: I64
    // left out intentionally
    // let code: (I64 | String | None)
    // let code_description: (CodeDescription | None)
    let message: String
    let related_information: Array[DiagnosticRelatedInformation]

    new ref create(range': LspPositionRange, severity': I64, message': String) =>
        range = range'
        severity = severity'
        message = message'
        related_information = Array[DiagnosticRelatedInformation].create(0)

    new val from_error(err: Error) =>
        this.range = LspPositionRange.from_single_pos(LspPosition.from_ast_pos(err.position))
        this.severity = DiagnosticSeverities.err()
        this.message = err.msg
        this.related_information = Array[DiagnosticRelatedInformation].create(err.infos.size())
        for info in err.infos.values() do
            let file_path = 
                try 
                    info.file as String
                else
                    try
                        err.file as String
                    else
                        continue
                    end
                end
            let file = Uris.from_path(file_path)
            let location = LspLocation.create(
                file, 
                LspPositionRange.from_single_pos(
                    LspPosition.from_ast_pos(info.position)
                )
            )
            this.related_information.push(
                DiagnosticRelatedInformation.create(location, info.msg)
            )
        end

    fun to_json(): JsonType =>
        var builder = Obj("range", this.range.to_json())(
            "severity", this.severity)(
            "source", "pony-lsp")(
            "message", this.message)
        if this.related_information.size() > 0 then
            var arr = Arr
            for rel_info in this.related_information.values() do
                arr = arr(rel_info.to_json())
            end
            builder = builder("relatedInformation", arr)
        end
        builder.build()



primitive DiagnosticSeverities
    fun tag err(): I64 => 1
    fun tag warning(): I64 => 2
    fun tag information(): I64 => 2
    fun tag hint(): I64 => 2

class val DiagnosticRelatedInformation
    let location: LspLocation
    let message: String

    new create(location': LspLocation, message': String) =>
        location = location'
        message = message'

    fun to_json(): JsonType =>
        Obj("location", this.location.to_json())(
            "message", this.message).build()